Theory HDeriv

(*  Title:      HOL/Nonstandard_Analysis/HDeriv.thy
    Author:     Jacques D. Fleuriot
    Copyright:  1998  University of Cambridge
    Conversion to Isar and new proofs by Lawrence C Paulson, 2004
*)

section ‹Differentiation (Nonstandard)›

theory HDeriv
  imports HLim
begin

text ‹Nonstandard Definitions.›

definition nsderiv :: "['a::real_normed_field ⇒ 'a, 'a, 'a] ⇒ bool"
    ("(NSDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
  where "NSDERIV f x :> D ⟷
    (∀h ∈ Infinitesimal - {0}. (( *f* f)(star_of x + h) - star_of (f x)) / h ≈ star_of D)"

definition NSdifferentiable :: "['a::real_normed_field ⇒ 'a, 'a] ⇒ bool"
    (infixl "NSdifferentiable" 60)
  where "f NSdifferentiable x ⟷ (∃D. NSDERIV f x :> D)"

definition increment :: "(real ⇒ real) ⇒ real ⇒ hypreal ⇒ hypreal"
  where "increment f x h =
    (SOME inc. f NSdifferentiable x ∧ inc = ( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x))"


subsection ‹Derivatives›

lemma DERIV_NS_iff: "(DERIV f x :> D) ⟷ (λh. (f (x + h) - f x) / h) ─0→⇩N⇩S D"
  by (simp add: DERIV_def LIM_NSLIM_iff)

lemma NS_DERIV_D: "DERIV f x :> D ⟹ (λh. (f (x + h) - f x) / h) ─0→⇩N⇩S D"
  by (simp add: DERIV_def LIM_NSLIM_iff)

lemma Infinitesimal_of_hypreal:
  "x ∈ Infinitesimal ⟹ (( *f* of_real) x::'a::real_normed_div_algebra star) ∈ Infinitesimal"
  by (metis Infinitesimal_of_hypreal_iff of_hypreal_def)

lemma of_hypreal_eq_0_iff: "⋀x. (( *f* of_real) x = (0::'a::real_algebra_1 star)) = (x = 0)"
  by transfer (rule of_real_eq_0_iff)

lemma NSDeriv_unique:
  assumes "NSDERIV f x :> D" "NSDERIV f x :> E"
  shows "NSDERIV f x :> D ⟹ NSDERIV f x :> E ⟹ D = E"
proof -
  have "∃s. (s::'a star) ∈ Infinitesimal - {0}"
    by (metis Diff_iff HDeriv.of_hypreal_eq_0_iff Infinitesimal_epsilon Infinitesimal_of_hypreal epsilon_not_zero singletonD)
  with assms show ?thesis
    by (meson approx_trans3 nsderiv_def star_of_approx_iff)
qed

text ‹First ‹NSDERIV› in terms of ‹NSLIM›.›

text ‹First equivalence.›
lemma NSDERIV_NSLIM_iff: "(NSDERIV f x :> D) ⟷ (λh. (f (x + h) - f x) / h) ─0→⇩N⇩S D"
  by (auto simp add: nsderiv_def NSLIM_def starfun_lambda_cancel mem_infmal_iff)

text ‹Second equivalence.›
lemma NSDERIV_NSLIM_iff2: "(NSDERIV f x :> D) ⟷ (λz. (f z - f x) / (z - x)) ─x→⇩N⇩S D"
  by (simp add: NSDERIV_NSLIM_iff DERIV_LIM_iff LIM_NSLIM_iff [symmetric])

text ‹While we're at it!›
lemma NSDERIV_iff2:
  "(NSDERIV f x :> D) ⟷
    (∀w. w ≠ star_of x ∧ w ≈ star_of x ⟶ ( *f* (λz. (f z - f x) / (z - x))) w ≈ star_of D)"
  by (simp add: NSDERIV_NSLIM_iff2 NSLIM_def)

lemma NSDERIVD5:
  "⟦NSDERIV f x :> D; u ≈ hypreal_of_real x⟧ ⟹
     ( *f* (λz. f z - f x)) u ≈ hypreal_of_real D * (u - hypreal_of_real x)"
  unfolding NSDERIV_iff2
  apply (case_tac "u = hypreal_of_real x", auto)
  by (metis (mono_tags, lifting) HFinite_star_of Infinitesimal_ratio approx_def approx_minus_iff approx_mult_subst approx_star_of_HFinite approx_sym mult_zero_right right_minus_eq)

lemma NSDERIVD4:
  "⟦NSDERIV f x :> D; h ∈ Infinitesimal⟧
    ⟹ ( *f* f)(hypreal_of_real x + h) - hypreal_of_real (f x) ≈ hypreal_of_real D * h"
  apply (clarsimp simp add: nsderiv_def)
  apply (case_tac "h = 0", simp)
  by (meson DiffI Infinitesimal_approx Infinitesimal_ratio Infinitesimal_star_of_mult2 approx_star_of_HFinite singletonD)

text ‹Differentiability implies continuity nice and simple "algebraic" proof.›
lemma NSDERIV_isNSCont: 
  assumes "NSDERIV f x :> D" shows "isNSCont f x"
  unfolding isNSCont_NSLIM_iff NSLIM_def
proof clarify
  fix x'
  assume "x' ≠ star_of x" "x' ≈ star_of x"
  then have m0: "x' - star_of x ∈ Infinitesimal - {0}"
    using bex_Infinitesimal_iff by auto
  then have "(( *f* f) x' - star_of (f x)) / (x' - star_of x) ≈ star_of D"
    by (metis ‹x' ≈ star_of x› add_diff_cancel_left' assms bex_Infinitesimal_iff2 nsderiv_def)
  then have "(( *f* f) x' - star_of (f x)) / (x' - star_of x) ∈ HFinite"
    by (metis approx_star_of_HFinite)  
  then show "( *f* f) x' ≈ star_of (f x)"
    by (metis (no_types) Diff_iff Infinitesimal_ratio m0 bex_Infinitesimal_iff insert_iff)
qed

text ‹Differentiation rules for combinations of functions
  follow from clear, straightforward, algebraic manipulations.›

text ‹Constant function.›

(* use simple constant nslimit theorem *)
lemma NSDERIV_const [simp]: "NSDERIV (λx. k) x :> 0"
  by (simp add: NSDERIV_NSLIM_iff)

text ‹Sum of functions- proved easily.›

lemma NSDERIV_add:
  assumes "NSDERIV f x :> Da" "NSDERIV g x :> Db"
  shows "NSDERIV (λx. f x + g x) x :> Da + Db"
proof -
  have "((λx. f x + g x) has_field_derivative Da + Db) (at x)"
    using assms DERIV_NS_iff NSDERIV_NSLIM_iff field_differentiable_add by blast
  then show ?thesis
    by (simp add: DERIV_NS_iff NSDERIV_NSLIM_iff)
qed

text ‹Product of functions - Proof is simple.›

lemma NSDERIV_mult:
  assumes "NSDERIV g x :> Db" "NSDERIV f x :> Da"
  shows "NSDERIV (λx. f x * g x) x :> (Da * g x) + (Db * f x)"
proof -
  have "(f has_field_derivative Da) (at x)" "(g has_field_derivative Db) (at x)"
    using assms by (simp_all add: DERIV_NS_iff NSDERIV_NSLIM_iff)
  then have "((λa. f a * g a) has_field_derivative Da * g x + Db * f x) (at x)"
    using DERIV_mult by blast
  then show ?thesis
    by (simp add: DERIV_NS_iff NSDERIV_NSLIM_iff)
qed

text ‹Multiplying by a constant.›
lemma NSDERIV_cmult: "NSDERIV f x :> D ⟹ NSDERIV (λx. c * f x) x :> c * D"
  unfolding times_divide_eq_right [symmetric] NSDERIV_NSLIM_iff
      minus_mult_right right_diff_distrib [symmetric]
  by (erule NSLIM_const [THEN NSLIM_mult])

text ‹Negation of function.›
lemma NSDERIV_minus: "NSDERIV f x :> D ⟹ NSDERIV (λx. - f x) x :> - D"
proof (simp add: NSDERIV_NSLIM_iff)
  assume "(λh. (f (x + h) - f x) / h) ─0→⇩N⇩S D"
  then have deriv: "(λh. - ((f(x+h) - f x) / h)) ─0→⇩N⇩S - D"
    by (rule NSLIM_minus)
  have "∀h. - ((f (x + h) - f x) / h) = (- f (x + h) + f x) / h"
    by (simp add: minus_divide_left)
  with deriv have "(λh. (- f (x + h) + f x) / h) ─0→⇩N⇩S - D"
    by simp
  then show "(λh. (f (x + h) - f x) / h) ─0→⇩N⇩S D ⟹ (λh. (f x - f (x + h)) / h) ─0→⇩N⇩S - D"
    by simp
qed

text ‹Subtraction.›
lemma NSDERIV_add_minus:
  "NSDERIV f x :> Da ⟹ NSDERIV g x :> Db ⟹ NSDERIV (λx. f x + - g x) x :> Da + - Db"
  by (blast dest: NSDERIV_add NSDERIV_minus)

lemma NSDERIV_diff:
  "NSDERIV f x :> Da ⟹ NSDERIV g x :> Db ⟹ NSDERIV (λx. f x - g x) x :> Da - Db"
  using NSDERIV_add_minus [of f x Da g Db] by simp

text ‹Similarly to the above, the chain rule admits an entirely
  straightforward derivation. Compare this with Harrison's
  HOL proof of the chain rule, which proved to be trickier and
  required an alternative characterisation of differentiability-
  the so-called Carathedory derivative. Our main problem is
  manipulation of terms.›


subsection ‹Lemmas›

lemma NSDERIV_zero:
  "⟦NSDERIV g x :> D; ( *f* g) (star_of x + y) = star_of (g x); y ∈ Infinitesimal; y ≠ 0⟧
    ⟹ D = 0"
  by (force simp add: nsderiv_def)

text ‹Can be proved differently using ‹NSLIM_isCont_iff›.›
lemma NSDERIV_approx:
  "NSDERIV f x :> D ⟹ h ∈ Infinitesimal ⟹ h ≠ 0 ⟹
    ( *f* f) (star_of x + h) - star_of (f x) ≈ 0"
  by (meson DiffI Infinitesimal_ratio approx_star_of_HFinite mem_infmal_iff nsderiv_def singletonD)

text ‹From one version of differentiability

        ‹f x - f a›
      ‹-------------- ≈ Db›
          ‹x - a›
›

lemma NSDERIVD1: 
    "⟦NSDERIV f (g x) :> Da;
     ( *f* g) (star_of x + y) ≠ star_of (g x);
     ( *f* g) (star_of x + y) ≈ star_of (g x)⟧
    ⟹ (( *f* f) (( *f* g) (star_of x + y)) -
         star_of (f (g x))) / (( *f* g) (star_of x + y) - star_of (g x)) ≈
        star_of Da"
  by (auto simp add: NSDERIV_NSLIM_iff2 NSLIM_def)

text ‹From other version of differentiability

      ‹f (x + h) - f x›
     ‹------------------ ≈ Db›
             ‹h›
›

lemma NSDERIVD2: "[| NSDERIV g x :> Db; y ∈ Infinitesimal; y ≠ 0 |]
      ==> (( *f* g) (star_of(x) + y) - star_of(g x)) / y
          ≈ star_of(Db)"
  by (auto simp add: NSDERIV_NSLIM_iff NSLIM_def mem_infmal_iff starfun_lambda_cancel)

text ‹This proof uses both definitions of differentiability.›
lemma NSDERIV_chain:
  "NSDERIV f (g x) :> Da ⟹ NSDERIV g x :> Db ⟹ NSDERIV (f ∘ g) x :> Da * Db"
  using DERIV_NS_iff DERIV_chain NSDERIV_NSLIM_iff by blast

text ‹Differentiation of natural number powers.›
lemma NSDERIV_Id [simp]: "NSDERIV (λx. x) x :> 1"
  by (simp add: NSDERIV_NSLIM_iff NSLIM_def del: divide_self_if)

lemma NSDERIV_cmult_Id [simp]: "NSDERIV ((*) c) x :> c"
  using NSDERIV_Id [THEN NSDERIV_cmult] by simp

lemma NSDERIV_inverse:
  fixes x :: "'a::real_normed_field"
  assumes "x ≠ 0" ― ‹can't get rid of \<^term>‹x ≠ 0› because it isn't continuous at zero›
  shows "NSDERIV (λx. inverse x) x :> - (inverse x ^ Suc (Suc 0))"
proof -
  {
    fix h :: "'a star"
    assume h_Inf: "h ∈ Infinitesimal"
    from this assms have not_0: "star_of x + h ≠ 0"
      by (rule Infinitesimal_add_not_zero)
    assume "h ≠ 0"
    from h_Inf have "h * star_of x ∈ Infinitesimal"
      by (rule Infinitesimal_HFinite_mult) simp
    with assms have "inverse (- (h * star_of x) + - (star_of x * star_of x)) ≈
      inverse (- (star_of x * star_of x))"
    proof -
      have "- (h * star_of x) + - (star_of x * star_of x) ≈ - (star_of x * star_of x)"
        using ‹h * star_of x ∈ Infinitesimal› assms bex_Infinitesimal_iff by fastforce
      then show ?thesis
        by (metis assms mult_eq_0_iff neg_equal_0_iff_equal star_of_approx_inverse star_of_minus star_of_mult)
    qed
    moreover from not_0 ‹h ≠ 0› assms
    have "inverse (- (h * star_of x) + - (star_of x * star_of x)) 
          = (inverse (star_of x + h) - inverse (star_of x)) / h"
      by (simp add: division_ring_inverse_diff inverse_mult_distrib [symmetric]
          inverse_minus_eq [symmetric] algebra_simps)
    ultimately have "(inverse (star_of x + h) - inverse (star_of x)) / h ≈
      - (inverse (star_of x) * inverse (star_of x))"
      using assms by simp
  }
  then show ?thesis by (simp add: nsderiv_def)
qed


subsubsection ‹Equivalence of NS and Standard definitions›

lemma divideR_eq_divide: "x /⇩R y = x / y"
  by (simp add: divide_inverse mult.commute)

text ‹Now equivalence between ‹NSDERIV› and ‹DERIV›.›
lemma NSDERIV_DERIV_iff: "NSDERIV f x :> D ⟷ DERIV f x :> D"
  by (simp add: DERIV_def NSDERIV_NSLIM_iff LIM_NSLIM_iff)

text ‹NS version.›
lemma NSDERIV_pow: "NSDERIV (λx. x ^ n) x :> real n * (x ^ (n - Suc 0))"
  by (simp add: NSDERIV_DERIV_iff DERIV_pow)

text ‹Derivative of inverse.›
lemma NSDERIV_inverse_fun:
  "NSDERIV f x :> d ⟹ f x ≠ 0 ⟹
    NSDERIV (λx. inverse (f x)) x :> (- (d * inverse (f x ^ Suc (Suc 0))))"
  for x :: "'a::{real_normed_field}"
  by (simp add: NSDERIV_DERIV_iff DERIV_inverse_fun del: power_Suc)

text ‹Derivative of quotient.›
lemma NSDERIV_quotient:
  fixes x :: "'a::real_normed_field"
  shows "NSDERIV f x :> d ⟹ NSDERIV g x :> e ⟹ g x ≠ 0 ⟹
    NSDERIV (λy. f y / g y) x :> (d * g x - (e * f x)) / (g x ^ Suc (Suc 0))"
  by (simp add: NSDERIV_DERIV_iff DERIV_quotient del: power_Suc)

lemma CARAT_NSDERIV:
  "NSDERIV f x :> l ⟹ ∃g. (∀z. f z - f x = g z * (z - x)) ∧ isNSCont g x ∧ g x = l"
  by (simp add: CARAT_DERIV NSDERIV_DERIV_iff isNSCont_isCont_iff)

lemma hypreal_eq_minus_iff3: "x = y + z ⟷ x + - z = y"
  for x y z :: hypreal
  by auto

lemma CARAT_DERIVD:
  assumes all: "∀z. f z - f x = g z * (z - x)"
    and nsc: "isNSCont g x"
  shows "NSDERIV f x :> g x"
proof -
  from nsc have "∀w. w ≠ star_of x ∧ w ≈ star_of x ⟶
       ( *f* g) w * (w - star_of x) / (w - star_of x) ≈ star_of (g x)"
    by (simp add: isNSCont_def)
  with all show ?thesis
    by (simp add: NSDERIV_iff2 starfun_if_eq cong: if_cong)
qed


subsubsection ‹Differentiability predicate›

lemma NSdifferentiableD: "f NSdifferentiable x ⟹ ∃D. NSDERIV f x :> D"
  by (simp add: NSdifferentiable_def)

lemma NSdifferentiableI: "NSDERIV f x :> D ⟹ f NSdifferentiable x"
  by (force simp add: NSdifferentiable_def)


subsection ‹(NS) Increment›

lemma incrementI:
  "f NSdifferentiable x ⟹
    increment f x h = ( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x)"
  by (simp add: increment_def)

lemma incrementI2:
  "NSDERIV f x :> D ⟹
    increment f x h = ( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x)"
  by (erule NSdifferentiableI [THEN incrementI])

text ‹The Increment theorem -- Keisler p. 65.›
lemma increment_thm:
  assumes "NSDERIV f x :> D" "h ∈ Infinitesimal" "h ≠ 0"
  shows "∃e ∈ Infinitesimal. increment f x h = hypreal_of_real D * h + e * h"
proof -
  have inc: "increment f x h = ( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x)"
    using assms(1) incrementI2 by auto
  have "(( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x)) / h ≈ hypreal_of_real D"
    by (simp add: NSDERIVD2 assms)
  then obtain y where "y ∈ Infinitesimal" 
    "(( *f* f) (hypreal_of_real x + h) - hypreal_of_real (f x)) / h = hypreal_of_real D + y"
    by (metis bex_Infinitesimal_iff2)
  then have "increment f x h / h = hypreal_of_real D + y"
    by (metis inc) 
  then show ?thesis
    by (metis (no_types) ‹y ∈ Infinitesimal› ‹h ≠ 0› distrib_right mult.commute nonzero_mult_div_cancel_left times_divide_eq_right)
qed

lemma increment_approx_zero: "NSDERIV f x :> D ⟹ h ≈ 0 ⟹ h ≠ 0 ⟹ increment f x h ≈ 0"
  by (simp add: NSDERIV_approx incrementI2 mem_infmal_iff)

end